We have a point

```
pt1 = {6.82, 1, 5.56};
```

And we have a line

```
ln = {7.82, 6.82, 6.56} + t {6, 12, -6};
```

We can get two more points from the line

```
pt2 = ln /. t -> 0;
pt3 = ln /. t -> 1;
```

Then we can borrow the example in the Mathematica help files for the `Cross[]`

function (ref/Cross)

```
u = pt2 - pt1;
v = pt3 - pt1;
w = Cross[u, v]
n = w/Norm[w]
Graphics3D[{Black, Arrow[Tube[{pt1, pt2}]], Arrow[Tube[{pt1, pt3}]],
Red, Arrow[{pt1, pt1 + 5 n}], White, InfinitePlane[{pt1, pt2, pt3}],
InfiniteLine[{pt2, pt3}]}, Axes -> True, PlotRangePadding -> 2]
```

And get that the unit normal vector is
`{-0.8757, 0.223964, -0.427772}`

and a plot showing the plane, the line, and the vectors. (n multiplied by 5 for visibility)

Also, I should point out, you don't need to assign values to t0 and t1 to get the unit normal vector because they will cancel out when we normalize.

```
pt2 = ln /. t -> t0;
pt3 = ln /. t -> t1;
u = pt2 - pt1;
v = pt3 - pt1;
w = FullSimplify[Rationalize[Cross[u, v]],
t0 \[Element] Reals && t1 \[Element] Reals && t0 != t1 && t0 < t1]
n = FullSimplify[Rationalize[w/Norm[w]],
t0 \[Element] Reals && t1 \[Element] Reals && t0 != t1 && t0 < t1]
n = SetPrecision[N[n], 3]
Graphics3D[{Black, Arrow[Tube[{pt1, pt2}]], Arrow[Tube[{pt1, pt3}]],
Red, Arrow[{pt1, pt1 + 5 n}], White, InfinitePlane[{pt1, pt2, pt3}],
InfiniteLine[{pt2, pt3}]}, Axes -> True, PlotRangePadding -> 2]
```

```
{(1173 (t0 - t1))/25, 12 (-t0 + t1), (573 (t0 - t1))/25}
{-(391/Sqrt[199362]), 50 Sqrt[2/99681], -(191/Sqrt[199362])}
{-0.876, 0.224, -0.428}
```